The method of using bat command to quickly create system restore point

Use bat Command to quickly create Win10 above Method of system restore point .

It is directly given here bat Code , Copy and paste into Notepad , Save as bat file , Run to see the effect .

@echo off
%1 mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit
cd /d "%~dp0"
:setType
echo ----------- Please select the restore point type -----------
echo 1. APPLICATION_INSTALL   Install application 
echo 2. APPLICATION_UNINSTALL   Uninstall app 
echo 3. DEVICE_DRIVER_INSTALL   Install device drivers 
echo 4. MODIFY_SETTINGS   Modify settings 
echo 5. CANCELLED_OPERATION   Canceled operation 
set /p type=
if "%type%"=="1" (
set typeStr=APPLICATION_INSTALL
echo  The current choice is APPLICATION_INSTALL Install application type 
)else if "%type%"=="2" (
set typeStr=APPLICATION_UNINSTALL
echo  The current choice is APPLICATION_UNINSTALL Uninstall app type 
)else if "%type%"=="3" (
set typeStr=DEVICE_DRIVER_INSTALL
echo  The current choice is DEVICE_DRIVER_INSTALL Install device drive type 
)else if "%type%"=="4" (
set typeStr=MODIFY_SETTINGS
echo  The current choice is MODIFY_SETTINGS Modify the setting type 
)else if "%type%"=="5" (
set typeStr=CANCELLED_OPERATION
echo  The current choice is CANCELLED_OPERATION Canceled operation type 
)else (
goto setType
)
echo ----------- Please enter the restore point name -----------
set /p name=
echo  The current set restore point name is %name%
echo  Carry out orders ：Checkpoint-Computer -Description "%name%" -RestorePointType "%typeStr%"

set command=Checkpoint-Computer -Description "%name%" -RestorePointType "%typeStr%"
echo %command%> "%temp%\temp.ps1"
::powershell Carry out orders 
powershell -executionpolicy remotesigned -file "%temp%\temp.ps1"

echo ######################  Execution completed  ######################
echo ######################  Execution completed  ######################
echo ######################  Execution completed  ######################
echo ######################  Execution completed  ######################
timeout /nobreak /t 3