Unity shader migrated from built-in rendering pipeline to URP

Unity stay URP Lieutenant general shader Update to HLSL Language , Use build-in shader Can't be directly in URP Use in
Here is about shader How to update

Reference resources From Built-in to URP

Update steps

1. Tags add to
   "RenderPipeline" = "UniversalPipeline"

2. CGPROGRAMENDCG Change for HLSLPROGRAMENDHLSL

3. #include "UnityCG.cginc"
   Change to #include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Core.hlsl"

4. fixed4 Change the type to half4

5. Function replacement cross reference

Build-in RP	URP
UnityObjectToClipPos(v.vertex);	TransformObjectToHClip(v.vertex.xyz);
mul(unity_ObjectToWorld,v.vertex).xyz	TransformObjectToWorld(v.vertex.xyz)
mul(float4(v.normal, 0.0),unity_WorldToObject).xyz	TransformObjectToWorldNormal(v.normal)

Code

Code up A simple uv flow shader
Built in rendering pipeline

// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
// Upgrade NOTE: replaced '_World2Object' with 'unity_WorldToObject'

Shader "Custom/liuguang"
{
    
    Properties
    {
    
        _FlowTex("Texture", 2D) = "white" {
    }
        _FlowTilling("Flow Tilling",Vector) = (1,1,0,0)
        _FlowSpeed("Flow Speed",Vector) = (1,1,0,0)

    }
    SubShader
    {
    
        Tags {
     "Queue" = "Transparent" }
        LOD 100

        Pass
        {
    
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
        // make fog work


            #include "UnityCG.cginc"

            struct appdata
            {
    
                float4 vertex : POSITION;
                float2 texcoord : TEXCOORD0;
                float3 normal : NORMAL;
            };

            struct v2f
            {
    
                float2 uv : TEXCOORD0;
                float4 pos : SV_POSITION;
                float3 pos_world : TEXCOORD1;
                float3 normal_world : TEXCOORD2;
                float3 pivot_world : TEXCOORD3;
            };


            sampler2D _FlowTex;
            float4 _FlowTilling;
            float4 _FlowSpeed;
    

            v2f vert(appdata v)
            {
    
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                float3 normal_world = mul(float4(v.normal, 0.0),unity_WorldToObject).xyz;
                o.normal_world = normalize(normal_world);
                o.pos_world = mul(unity_ObjectToWorld,v.vertex).xyz;
                o.pivot_world = mul(unity_ObjectToWorld, float4(0, 0, 0, 1)).xyz;
                o.uv = v.texcoord;
                return o;
            }

            fixed4 frag(v2f i) : SV_Target
            {
    
                half2 uv_flow = (i.pos_world.xy - i.pivot_world.xy) * _FlowTilling.xy;
                uv_flow = uv_flow + _Time.y * _FlowSpeed.xy;
                float4 flow_rgba = tex2D(_FlowTex, uv_flow);
                return flow_rgba;
            }
            ENDCG
        }
    }
}

URP

Shader "Custom/flowlight"
{
    
    Properties
    {
    
        _FlowTex("Texture", 2D) = "white" {
    }
        _FlowTilling("Flow Tilling",Vector) = (1,1,0,0)
        _FlowSpeed("Flow Speed",Vector) = (1,1,0,0)

    }
    SubShader
    {
    
        Tags {
     "RenderType" = "Opaque"  "RenderPipeline" = "UniversalPipeline" }
        LOD 100

        Pass
        {
    
            HLSLPROGRAM
            #pragma vertex vert
            #pragma fragment frag

            #include "Packages/com.unity.render-pipelines.universal/ShaderLibrary/Core.hlsl"

            struct appdata
            {
    
                float4 vertex : POSITION;
                float2 texcoord : TEXCOORD0;
                float3 normal : NORMAL;
            };

            struct v2f
            {
    
                float2 uv : TEXCOORD0;
                float4 pos : SV_POSITION;
                float3 pos_world : TEXCOORD1;
                float3 normal_world : TEXCOORD2;
                float3 pivot_world : TEXCOORD3;
            };


            sampler2D _FlowTex;
            float4 _FlowTilling;
            float4 _FlowSpeed;


            v2f vert(appdata v)
            {
    
                v2f o;
                o.pos = TransformObjectToHClip(v.vertex.xyz);
                float3 normal_world = TransformObjectToWorldNormal(v.normal);
                o.normal_world = normalize(normal_world);
                o.pos_world = TransformObjectToWorld(v.vertex.xyz);
                o.pivot_world = TransformObjectToWorld(float3(0,0,0));
                o.uv = v.texcoord;
                return o;
            }

            half4  frag(v2f i) : SV_Target
            {
    
                half2 uv_flow = (i.pos_world.xy - i.pivot_world.xy) * _FlowTilling.xy;
                uv_flow = uv_flow + _Time.y * _FlowSpeed.xy;
                float4 flow_rgba = tex2D(_FlowTex, uv_flow);
                return flow_rgba;
            }
            ENDHLSL
        }
    }
}